Example 8: Exporting to Excel with progress

Uses ExportToXLSX to write the grid’s data to an Excel workbook, and OnExportProgress to show the progress.

Scenario

An Export button writes the products to Products.xlsx: only the selected rows when some are selected, all of them otherwise. A progress bar follows the export, and the file name is shown at the end.

Units

Besides EgFireGrid: System.IOUtils (TPath), System.SysUtils (Exception) and FMX.DialogService (TDialogService).

The handlers

procedure TForm1.BtnExportClick(Sender: TObject);
var
  FileName: string;
begin
  FileName := TPath.Combine(TPath.GetDocumentsPath, 'Products.xlsx');
  ProgressBar1.Value := 0;
  ProgressBar1.Visible := True;
  try
    try
      // Memo text cut at 1000 characters; only the selected rows when there are any
      Grid1.ExportToXLSX(FileName, 1000, Grid1.SelectedRowCount > 0);
      TDialogService.ShowMessage('Exported to ' + FileName);
    except
      on E: Exception do
        TDialogService.ShowMessage('Export failed: ' + E.Message);
    end;
  finally
    ProgressBar1.Visible := False;
  end;
end;

procedure TForm1.Grid1ExportProgress(Sender: TObject; var PercentDone: Integer);
begin
  ProgressBar1.Value := PercentDone;
{$IFDEF MSWINDOWS}
  Application.ProcessMessages;  // lets the bar repaint while the export runs
{$ENDIF}
end;

Why it works this way

• What is exported: the visible columns bound to a field, in the grid’s order, with each value’s Excel type (numbers, dates and booleans stay numbers, dates and booleans in Excel). Pictures, plain BLOBs and columns with no field are left out, and so is the grid’s look (colours, fonts, formats).
• All the records, not only those on screen, in the dataset’s current order and filter; with the third parameter True and a selection, only the selected ones.
• The file must be writable: the documents folder is writable on both platforms. On Android, share the file afterwards (for example with an ACTION_SEND intent) to let the user open it in another app.
• The export runs in the calling thread, so nothing repaints unless the progress handler lets it. On Windows Application.ProcessMessages does; keep the user from starting another action meanwhile (the button can be disabled during the export).
• An edit still open in the grid is ended and written first, and the dataset’s current record is restored at the end.

See Also

• ExportToXLSX
• OnExportProgress
• SelectedRowIds
• Examples