Example 5: Values that are not fields

Uses <var> markers and OnGetVariableValue to put in titles and cells values that are not fields of the dataset, and VariableRowIndex to compute a value for the row being drawn.

Scenario

• The Price title shows the currency in use on a second line: Price<br>(<var>Currency</var>).
• The Name cells show the product and its category on two lines, from the fields alone.
• A column with no field shows how many days ago each product was updated.

Setup

// FormCreate
Grid1.ColumnByFieldName('Price').Title.Caption := 'Price<br>(<var>Currency</var>)';
Grid1.HeaderHeight := 40;   // room for the second line of the title
Grid1.RowHeight := 36;      // room for two lines in the cells

Units

Besides EgFireGrid: System.SysUtils (SameText, IntToStr, FormatSettings, Date) and System.Variants (VarIsNull, VarToDateTime).

The handlers

procedure TForm1.Grid1BeforeDrawCell(Sender: TObject; Column: TEgFireGridColumn; RowIndex: Integer;
  Cell: TEgFireGridCellControl; var Text: string);
begin
  if SameText(Column.FieldName, 'Name') then
    // Both names are fields: the grid replaces them with the fields' text in this row
    Text := '<var>Name</var><br><var>Category</var>'
  else if SameText(Column.Title.Caption, 'Updated') then
    Text := '<var>DaysSinceUpdate</var> days';
end;

procedure TForm1.Grid1GetVariableValue(Sender: TObject; const VarID: string; var Value: string);
var
  UpdatedAt: Variant;
begin
  if SameText(VarID, 'Currency') then
    Value := FormatSettings.CurrencyString
  else if SameText(VarID, 'DaysSinceUpdate') and (Grid1.VariableRowIndex >= 0) then
  begin
    UpdatedAt := Grid1.RowSource.GetValue(Grid1.VariableRowIndex, 'UpdatedAt');
    if not VarIsNull(UpdatedAt) then
      Value := IntToStr(Trunc(Date - VarToDateTime(UpdatedAt)));
  end;
end;

Why it works this way

• Field names need no handler: in a cell, a marker naming a field of the dataset is replaced by that field’s text in the same row. OnGetVariableValue is asked only for the other names, and for every marker in a title (a title belongs to no row).
• VariableRowIndex is the window row of the marker being resolved, -1 in a title; the handler reads that row’s fields with RowSource.GetValue.
• <br> is a line break. The row and title heights do not grow by themselves, hence the two heights in the setup.
• Markers are not resolved in memo columns, and a value returned by the handler is not scanned for markers again.

See Also

• OnGetVariableValue
• VariableRowIndex
• OnBeforeDrawCell
• Examples